DOS-Forum

Code: Alles auswählen

Program SetRTC;
(*Setzt die Zeit der RTC des Wugo Systemboard PC II*)

uses crt;
var sek,min,std,tag,mon,oldmonth,oldyear:byte;
    pstr:string;

(* Die Zaehler arbeiten im BCD-Modus, so dass konvertiert werden muss*)
function bytetobcd(input:byte):byte;
 var h1,h2:byte;
 begin
  h1:=input div 10;h2:=input mod 10;
  bytetobcd:=(h1 shl 4)+h2;
 end;

function bcdtobyte(input:byte):byte;
 var h1,h2:byte;
 begin
  h1:=input shr 4;h2:=input and $0F;
  bcdtobyte:=(h1*10)+h2;
 end;

 begin
  sek:=bcdtobyte(Port[$242]);min:=bcdtobyte(Port[$243]);std:=bcdtobyte(Port[$244]);
  tag:=bcdtobyte(Port[$246]);mon:=bcdtobyte(Port[$247]);

  (* Workaround
     Der Uhrenbaustein zaehlt keine Jahre, also speichere ich
     Jahr und Monat in dem Ram des Bausteins.
     Ist der gespeicherte Monat groesser als der aktuelle Monat,
     hat ein Jahreswechsel stattgefunden, in dem Fall wird das Jahr erhoeht
     und Monat/Jahr neu gespeichert.
     Sofern der Rechner alle 11Monate eingeschalten wird funktioniert das.
     Das Jahr hat einen Wertebereich von 2000-2255.*)
  oldmonth:=Port[$248];oldyear:=Port[$249];
  if oldmonth>mon then begin
     oldmonth:=mon;
     inc(oldyear);
     Port[$248]:=oldmonth;
     Port[$249]:=oldyear;
     end;
  (*Workaround Ende*)

  writeln('Datum: ',tag,'.',mon,'.',word(2000+oldyear));
  writeln('Zeit: ',std,':',min,':',sek);
  writeln('Einstellen mit "setrtc n"');
  if paramcount>0 then begin
     pstr:=Paramstr(1);
     if pstr[1]='n' then begin
        writeln('Jahr')  ;readln(oldyear);
        writeln('Monat') ;readln (mon);
        writeln('Tag')   ;readln(tag);
        writeln('Stunde');readln(std);
        writeln('Minute');readln(min);
        Port[$243]:=bytetobcd(min);
        Port[$244]:=bytetobcd(std);
        Port[$246]:=bytetobcd(tag);
        Port[$247]:=bytetobcd(mon);
        Port[$248]:=mon;            (*speichern von Jahr/Monat fuer den*)
        Port[$249]:=oldyear;        (*Workaround*)
        end;
     end;
  (*schreiben von Datum und Zeit in die normale RTC (damit DOS die Zeit kennt)*)
  asm
   mov ch,std
   mov cl,min
   mov dh,sek
   mov dl,$00
   mov ah,$2D
   int $21
   mov cx,$00
   mov cl,oldyear
   add cx,2000
   mov dh,mon
   mov dl,tag
   mov ah,$2B
   int $21
  end;
 end.